PseInt – Contar el número de cifras de un número

23/10/20230 comentarios

Hola a todos, hoy os voy a enseñar como podemos contar el número de cifras de un número en PseInt.

Un ejercicio muy interesante es saber cuántas cifras tiene un número, tenemos varias formas de hacerlo, veremos todas.

Preparando todo lo necesario para contar el número de cifras

En primer lugar, es tener instalado PseInt, lo puedes descargar aquí.

Lo que necesitamos es declarar dos variables:

num: Número pedido al usuario.
cifras: Número de cifras del número. Lo inicializamos a 0.

Algoritmo CuentaCifras
	
	definir num, cifras Como Entero;
	
	Escribir "Escribe un numero";
	leer num;
	
	cifras <- 0;
	
FinAlgoritmo

Algoritmo para contar el número de cifras (versión 1)

Para esta primera versión, convertiremos el número a absoluto para no tener problemas con los números negativos, seguidamente, contaremos las cifras con un bucle dividiendo entre 10 truncando el resultado.

Si nos dan un 0, le indicaremos que el número de cifras es 1.

Algoritmo CuentaCifras
	
	definir num, cifras Como Entero;
	
	Escribir "Escribe un numero";
	leer num;
	
	cifras <- 0;
	
	Si num = 0 Entonces
		cifras <- 1;
	SiNo
		num <- ABS(num);
		
		Mientras num > 0 Hacer
			cifras <- cifras + 1;
			num <- trunc(num / 10);
		Fin Mientras
		
		
	Fin Si
	
	Escribir "El número de cifras es de ", cifras;
	
FinAlgoritmo

Algoritmo para contar el número de cifras (versión 2)

Esta versión es más sencilla, lo único que hacemos es sacar la longitud del número convertido a texto, para ello, es necesario pasar el número a absoluto.

Algoritmo CuentaCifras 
	definir num, cifras Como Entero; 
	Escribir "Escribe un numero"; 
	leer num; cifras <- 0; 
	
	num <- abs(num);
	cifras <- Longitud(ConvertirATexto(num));
	
	Escribir "El número de cifras es de ", cifras; 
FinAlgoritmo

Subproceso

Podemos usar un subproceso para calcularlo de forma sencilla, para ello, le pasamos un numero y lo pasamos a absoluto. Puedes usar la versión que quieras.

SubProceso cifras <- CuentaCifras ( num )
	definir cifras Como Entero; 
	cifras <- 0; 
	
	Si num = 0 Entonces 
		cifras <- 1; 
	SiNo 
		num <- ABS(num); 
		Mientras num > 0 Hacer 
			cifras <- cifras + 1; 
			num <- trunc(num / 10); 
		Fin Mientras 
	Fin Si 
	
Fin SubProceso


Algoritmo CuentaCifrasAlgoritmo
	
	definir num, cifras Como Entero; 
	Escribir "Escribe un numero"; 
	leer num; 
	
	cifras <- CuentaCifras(num); 
	
	Escribir "El número de cifras es de ", cifras;
	
FinAlgoritmo