Rellenar una matriz de números aleatorios en PseInt

Hola a todos, hoy os voy a explicar como rellenar una matriz de números aleatorios en PseInt.

Puede ser que en algunos de nuestros procesos necesitemos rellenar una matriz de números aleatorios en PseInt.

Os dejo un tutorial de cómo generar números aleatorios.

https://www.discoduroderoer.es/como-generar-un-numero-aleatorio-en-pseint

La idea es recorrer la matriz y para cada posición generar un número aleatorio.

En nuestro caso, vamos a generar números entre 1 y 9.

Proceso testRellenarMatriz
	
	Dimension matriz(5,6);
	definir i, j, numFilas, numColumnas, minimo, maximo, matriz como numero;
	numFilas <- 5;
	numColumnas <- 6;
	minimo <- 1;
	maximo <- 9;
	
	Para i<-0 Hasta numFilas -1 Con Paso 1 Hacer
		Para j<-0 Hasta numColumnas -1 Con Paso 1 Hacer
			matriz(i,j) <- numeroAleatorioEntre(minimo, maximo);
			Escribir matriz(i,j), " " Sin Saltar;
		FinPara
		Escribir "";
	FinPara
	
FinProceso

//Genera un numero aleatorio entre el minimo y máximo incluidos
SubProceso numeroAzar <- numeroAleatorioEntre(minimo, maximo)
	definir numeroAzar como numero;
	numeroAzar <- 0;
	
	Repetir
		
		numeroAzar <- AZAR(maximo+1); Hasta Que numeroAzar >= minimo Y numeroAzar<=maximo
	
	
FinSubProceso

Este es el resultado:

Podemos hacerlo en un subproceso:

//Rellena una matriz de numeros aleatorios entre un mínimo y un máximo, números mínimo y máximo incluidos.
SubProceso rellenarMatrizAleatorios(matriz, numFilas, numColumnas, minimo, maximo)
	
	definir i,j como numero;
	
	Para i<-0 Hasta numFilas -1 Con Paso 1 Hacer
		Para j<-0 Hasta numColumnas -1 Con Paso 1 Hacer
			matriz(i,j) <- numeroAleatorioEntre(minimo, maximo);
		FinPara
	FinPara
	
FinSubProceso

Así cambiaria nuestro código:

Proceso testRellenarMatriz
	
	Dimension matriz(5,6);
	definir i, j, numFilas, numColumnas, minimo, maximo, matriz como numero;
	numFilas <- 5;
	numColumnas <- 6;
	minimo <- 1;
	maximo <- 9;
	
	// Rellenamos la matriz
	rellenarMatrizAleatorios(matriz, numFilas, numColumnas, minimo, maximo);
	
	// Mostramos la matriz
	Para i<-0 Hasta numFilas -1 Con Paso 1 Hacer
		Para j<-0 Hasta numColumnas -1 Con paso 1 Hacer
			Escribir matriz(i,j), " " Sin Saltar;
		FinPara
		Escribir "";
	FinPara
	
FinProceso

//Genera un numero aleatorio entre el minimo y máximo incluidos
SubProceso numeroAzar <- numeroAleatorioEntre(minimo, maximo)
	definir numeroAzar como numero;
	numeroAzar <- 0;
	
	Repetir
		numeroAzar <- AZAR(maximo+1); Hasta Que numeroAzar >= minimo Y numeroAzar<=maximo
	
	
FinSubProceso

//Rellena una matriz de numeros aleatorios entre un mínimo y un máximo, números mínimo y máximo incluidos.
SubProceso rellenarMatrizAleatorios(matriz, numFilas, numColumnas, minimo, maximo)
	
	definir i,j como numero;
	
	Para i<-0 Hasta numFilas -1 Con Paso 1 Hacer
		Para j<-0 Hasta numColumnas -1 Con Paso 1 Hacer
			matriz(i,j) <- numeroAleatorioEntre(minimo, maximo);
		FinPara
	FinPara
	
FinSubProceso

Recordar que tenemos más subprocesos útiles en nuestra biblioteca en github.

Y no te olvides que tenemos un curso en udemy de PseInt.

Curso iniciación pseudocodigo con Pseint

Espero que os sea de ayuda. Si tenéis dudas, preguntad. Estamos para ayudarte.